home *** CD-ROM | disk | FTP | other *** search
/ The PC-SIG Library 10 / The PC-Sig Library - Shareware for the IBM PC and Compatibles (PC-SIG)(Tenth Edition Disks 1-2804)(1991).iso / PC_SIGCD / 02 / 3 / DISK0236.ZIP / FPRINT.TRY < prev    next >
Text File  |  1984-09-01  |  3KB  |  49 lines
  1. 10 '               FPRINT.TRY - Memory dump program
  2. 20 '
  3. 30 ' Character table: Segment &HF000, Location &HFA6E through &HFE66
  4. 40 '
  5. 50 '
  6. 60 COLOR 7,0: KEY OFF: WIDTH 80: GOSUB 270
  7. 70 COLOR 9,0: CLS: PRINT "MEMORY DUMP by Gerry J. Danen": PRINT: PRINT: COLOR 14,0
  8. 80 INPUT "Define Segment?    ",DS: PRINT
  9. 90 INPUT "Starting Location? ",SL
  10. 100 INPUT "Ending Location?   ",EL
  11. 110 IF EL=0 THEN EL=SL
  12. 120 ' Loop to dump memory
  13. 130 '
  14. 140 DEF SEG=DS: GOSUB 260: LN=1
  15. 150 FOR L=SL TO EL
  16. 160   N=PEEK(L): B$="00000000": NSAV=N: N$=CHR$(N): IF N<32 THEN N$=CHR$(250)
  17. 170   FOR J=1 TO 8: IF N<2^(8-J) THEN 180 ELSE MID$(B$,J,1)="1": N=N-2^(8-J)
  18. 180   NEXT J
  19. 190   LN=LN+1: IF LN>22 THEN GOSUB 230
  20. 200   LOCATE LN,11: PRINT B$; "  "; N$; "  "; NSAV; TAB(29); HEX$(NSAV); TAB(36); DS; L; TAB(50); HEX$(DS); "-"; HEX$(L)
  21. 210 NEXT L
  22. 220 DEF SEG: END
  23. 230 ' heading
  24. 240 '
  25. 250 COLOR 12,0: LOCATE 24,11: INPUT "Press [Enter] to continue", QAZ$
  26. 260 COLOR 10,0: CLS: LN=2: LOCATE 1,11: PRINT "--bits-- char/int/hex     Seg Addr /Hex Seg Addr": COLOR 7,0: RETURN
  27. 270 ' Title screen
  28. 280 '
  29. 290 CLS: COLOR 12,0
  30. 300 PRINT "╔═════════════════════════════════════════════════════════════════════════════╗"
  31. 310 PRINT "║  ╔═══════════════════════════════════════════════════════════════════════╗  ║"
  32. 320 PRINT "║  ║  ╔═════════════════════════════════════════════════════════════════╗  ║  ║"
  33. 330 PRINT "║  ║  ║                                                                 ║  ║  ║"
  34. 340 PRINT "║  ║  ║                                                                 ║  ║  ║"
  35. 350 PRINT "║  ║  ║                                                                 ║  ║  ║"
  36. 360 PRINT "║  ║  ║                                                                 ║  ║  ║"
  37. 370 PRINT "║  ║  ║                                                                 ║  ║  ║"
  38. 380 PRINT "║  ║  ║                                                                 ║  ║  ║"
  39. 390 PRINT "║  ║  ║                                                                 ║  ║  ║"
  40. 400 PRINT "║  ║  ║                                                                 ║  ║  ║"
  41. 410 PRINT "║  ║  ╚═════════════════════════════════════════════════════════════════╝  ║  ║"
  42. 420 PRINT "║  ╚═══════════════════════════════════════════════════════════════════════╝  ║"
  43. 430 PRINT "╚═════════════════════════════════════════════════════════════════════════════╝"
  44. 440 COLOR 9,0: LOCATE 6,21: PRINT "MEMORY DUMP PROGRAM by Gerry J. Danen"
  45. 450 COLOR 9,0: LOCATE 9,33: PRINT "Version V1.00"
  46. 460 LOCATE 22,31: COLOR 14,0: PRINT "Press any key...";
  47. 470 S$=INKEY$: IF S$="" THEN 470
  48. 480 RETURN
  49.